1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
;;; cape-char.el --- Character completion functions -*- lexical-binding: t -*-
;; Copyright (C) 2021-2023 Free Software Foundation, Inc.
;; This file is part of GNU Emacs.
;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;; This package provides the `cape-tex', `cape-sgml' and `cape-rfc1345'
;; completion functions.
;;; Code:
(require 'cape)
;; Declare as pure function which is evaluated at compile time. We don't use a
;; macro for this computation since packages like `helpful' will
;; `macroexpand-all' the expensive `cape-char--define' macro calls.
(eval-when-compile
(defun cape-char--translation (method regexp)
"Return character translation hash for METHOD.
REGEXP is the regular expression matching the names."
(declare (pure t))
(save-window-excursion
(describe-input-method method)
(with-current-buffer "*Help*"
(let ((lines
(split-string
(replace-regexp-in-string
"\n\n\\(\n\\|.\\)*" ""
(replace-regexp-in-string
"\\`\\(\n\\|.\\)*?----\n" ""
(replace-regexp-in-string
"\\`\\(\n\\|.\\)*?KEY SEQUENCE\n-+\n" ""
(buffer-string))))
"\n"))
(hash (make-hash-table :test #'equal)))
(dolist (line lines)
(let ((beg 0) (len (length line)))
(while (< beg len)
(let* ((ename (next-single-property-change beg 'face line len))
(echar (next-single-property-change ename 'face line len)))
(when (and (get-text-property beg 'face line) (< ename len) (<= echar len))
(let ((name (string-trim (substring-no-properties line beg ename)))
(char (string-trim (substring-no-properties line ename echar))))
(when (and (string-match-p regexp name) (= (length char) 1))
(puthash name (aref char 0) hash))))
(setq beg echar)))))
(kill-buffer)
hash)))))
(defmacro cape-char--define (name method &rest prefix)
"Define character translation capf.
NAME is the name of the capf.
METHOD is the input method.
PREFIX are the prefix characters."
(let ((capf (intern (format "cape-%s" name)))
(prefix-required (intern (format "cape-%s-prefix-required" name)))
(hash (intern (format "cape--%s-hash" name)))
(ann (intern (format "cape--%s-annotation" name)))
(docsig (intern (format "cape--%s-docsig" name)))
(exit (intern (format "cape--%s-exit" name)))
(properties (intern (format "cape--%s-properties" name))))
`(progn
(defvar ,hash (cape-char--translation
,method
,(concat "\\`" (regexp-opt (mapcar #'char-to-string prefix)))))
(defcustom ,prefix-required t
,(format "Initial prefix is required for `%s' to trigger." capf)
:type 'boolean
:group 'cape)
(defun ,ann (name)
(when-let (char (gethash name ,hash))
(format " %c" char)))
(defun ,docsig (name)
(when-let (char (gethash name ,hash))
(format "%s (%s)"
(get-char-code-property char 'name)
(char-code-property-description
'general-category
(get-char-code-property char 'general-category)))))
(defun ,exit (name status)
(unless (eq status 'exact)
(when-let (char (gethash name ,hash))
(delete-region (max (point-min) (- (point) (length name))) (point))
(insert (char-to-string char)))))
(defvar ,properties
(list :annotation-function #',ann
:company-docsig #',docsig
:exit-function #',exit
:company-kind (lambda (_) 'text)
:exclusive 'no)
,(format "Completion extra properties for `%s'." name))
(defun ,capf (&optional interactive)
,(format "Complete unicode character at point.
Uses the same input format as the %s input method,
see (describe-input-method %S). If INTERACTIVE
is nil the function acts like a capf." method method)
(interactive (list t))
(if interactive
;; NOTE: Disable cycling since replacement breaks it.
(let (completion-cycle-threshold ,prefix-required)
(when (memq last-input-event ',prefix)
(self-insert-command 1 last-input-event))
(cape--interactive #',capf))
(when-let (bounds
(cond
((thing-at-point-looking-at
,(concat (regexp-opt (mapcar #'char-to-string prefix)) "[^ \n\t]*" ))
(cons (match-beginning 0) (match-end 0)))
((not ,prefix-required) (cons (point) (point)))))
(append
(list (car bounds) (cdr bounds)
(cape--table-with-properties ,hash :category ',capf))
,properties)))))))
;;;###autoload (autoload 'cape-tex "cape-char" nil t)
;;;###autoload (autoload 'cape-sgml "cape-char" nil t)
;;;###autoload (autoload 'cape-rfc1345 "cape-char" nil t)
(cape-char--define tex "TeX" ?\\ ?^ ?_)
(cape-char--define sgml "sgml" ?&)
(cape-char--define rfc1345 "rfc1345" ?&)
(provide 'cape-char)
;;; cape-char.el ends here
|
